آموزش گام به گام آردوینو (بخش ششم : استفاده از تابع millis)

گاهی نیاز دارید دو عمل را به صورت همزمان انجام دهید. بطور مثال ممکن است بخواهید همزمان با خواندن یک ورودی یا فشار یک دکمه، LED را چشمک زن کنید (یا یک عمل حساس به زمان دیگر). در این حالت نمی توانید از delay() استفاده  کنید، یا سایر عملیات ها را در برنامه، تا زمانی که یک LED چشمک می زند، متوقف کنید. اگر در جریان delay()، دکمه ای فشرده شود، برنامه ممکن است فشرده شدن دکمه را نبیند و از دست بدهد. این اسکچ نشان می دهد که چطور یک LED بدون دستورdelay() چشمک می زند. این برنامه، آخرین عملی که آردوینو روی LED انجام داده است را نگه می دارد. سپس هر بار در حلقه loop()، چک می شود که آیا زمان دلخواه ما را طی کرده است یا نه؟ اگر چنین بود، LED را به حالت مخالف وضعیت فعلی در می آورد.گاهی نیاز دارید دو عمل را به صورت همزمان انجام دهید. بطور مثال ممکن است بخواهید همزمان با خواندن یک ورودی یا فشار یک دکمه، LED را چشمک زن کنید (یا یک عمل حساس به زمان دیگر). در این حالت نمی توانید از delay() استفاده  کنید، یا سایر عملیات ها را در برنامه، تا زمانی که یک LED چشمک می زند، متوقف کنید. اگر در جریان delay()، دکمه ای فشرده شود، برنامه ممکن است فشرده شدن دکمه را نبیند و از دست بدهد. این اسکچ نشان می دهد که چطور یک LED بدون دستورdelay() چشمک می زند. این برنامه، آخرین عملی که آردوینو روی LED انجام داده است را نگه می دارد. سپس هر بار در حلقه loop()، چک می شود که آیا زمان دلخواه ما را طی کرده است یا نه؟ اگر چنین بود، LED را به حالت مخالف وضعیت فعلی در می آورد.

سخت افزار مورد نیاز

• برد آردوینو
• یک LED

مدار

برای ساخت مدار، یک LED بردارید و پایه بلند آن یعنی پایه مثبت(که آنود نامیده می شود) را به پین 13 و پایه کوتاه یعنی پایه منفی(که کاتود نامیده می شود) را به زمین وصل کنید. بعد برد آردوینو را به کامپیوتر متصل کرده، برنامه آردوینو را اجرا و کد زیر را وارد کنید.

شماتیک

کد
کد زیر از تابع millis() استفاده می کند، دستوری که تعداد میلی ثانیه را از زمانی که برد آردوینو برنامه فعلی را برای چشمک زدن LED اجرا می کند، بر می گرداند.

/* Blink without Delay

 Turns on and off a light emitting diode (LED) connected to a digital
 pin, without using the delay() function.  This means that other code
 can run at the same time without being interrupted by the LED code.

 The circuit:
 * Use the onboard LED.
 * Note: Most Arduinos have an on-board LED you can control. On the UNO, MEGA and ZERO 
  it is attached to digital pin 13, on MKR1000 on pin 6. LED_BUILTIN is set to
  the correct LED pin independent of which board is used.
  If you want to know what pin the on-board LED is connected to on your Arduino model, check
  the Technical Specs of your board  at https://www.arduino.cc/en/Main/Products

 created 2005
 by David A. Mellis
 modified 8 Feb 2010
 by Paul Stoffregen
 modified 11 Nov 2013
 by Scott Fitzgerald
 modified 9 Jan 2017
 by Arturo Guadalupi


 This example code is in the public domain.

 http://www.arduino.cc/en/Tutorial/BlinkWithoutDelay
 */

// constants won't change. Used here to set a pin number :
const int ledPin =  LED_BUILTIN;// the number of the LED pin

// Variables will change :
int ledState = LOW;             // ledState used to set the LED

// Generally, you should use "unsigned long" for variables that hold time
// The value will quickly become too large for an int to store
unsigned long previousMillis = 0;        // will store last time LED was updated

// constants won't change :
const long interval = 1000;           // interval at which to blink (milliseconds)

void setup() {
  // set the digital pin as output:
  pinMode(ledPin, OUTPUT);
}

void loop() {
  // here is where you'd put code that needs to be running all the time.

  // check to see if it's time to blink the LED; that is, if the
  // difference between the current time and last time you blinked
  // the LED is bigger than the interval at which you want to
  // blink the LED.
  unsigned long currentMillis = millis();

  if (currentMillis - previousMillis >= interval) {
    // save the last time you blinked the LED
    previousMillis = currentMillis;

    // if the LED is off turn it on and vice-versa:
    if (ledState == LOW) {
      ledState = HIGH;
    } else {
      ledState = LOW;
    }

    // set the LED with the ledState of the variable:
    digitalWrite(ledPin, ledState);
  }
}

نویسنده: گروه IRSE